as a way to ease the transition from Max to Pd, I'm writing a plugin that implements Max's hotkeys in Pd.
I started from the super helpful script by Monetus and already got some stuff working...

now I'd like to open an object's help by alt+clicking on it. Here's what I have now:

bind all <Alt-Button-1> "::pdtk_canvas::done_popup %W 2"

..this leads to a "no such object" error, since (I guess) %W points to the window, not the object being clicked. I've looked everywhere but I can't figure out how to reference the object itself...

@rvirmoors the issue is that tcl/tk is reporting %W as the canvas, not the toplevel window the canvas is in.
this would work: (edit: changed to cross-platform version)

apply {{} {
    # on Mac OS X/Aqua, the Alt/Option key is called Option in Tcl
    if {$::windowingsystem eq "aqua"} {
        set alt "Option"
    } else {
        set alt "Alt"
    }
    bind all <$alt-Button-1> {
        set win [winfo toplevel %W]
        if {[winfo class $win] eq "PatchWindow"} {
            set ::popup_xcanvas %x
            set ::popup_ycanvas %y
            ::pdtk_canvas::done_popup $win 2
        }
    }
}}

@seb-harmonik.ar nice! thanks a lot

thinking about this a bit more, I think it might be easier to just intercept the proc for making the bindings if they should be set to that thing exclusively (if you don't want the alt-click to do what it normally does as well as open a help file):

rename ::pd_bindings::patch_bindings original_bindings
# this is for canvas windows
proc ::pd_bindings::patch_bindings {mytoplevel} {
    # set normal bindings
    original_bindings $mytoplevel
    set tkcanvas [tkcanvas_name $mytoplevel]

    # on Mac OS X/Aqua, the Alt/Option key is called Option in Tcl
    if {$::windowingsystem eq "aqua"} {
        set alt "Option"
    } else {
        set alt "Alt"
    }

    bind $tkcanvas <$alt-ButtonPress-1> {
        set win [winfo toplevel %W]
        if {[winfo class $win] eq "PatchWindow"} {
            set ::popup_xcanvas %x
            set ::popup_ycanvas %y
            ::pdtk_canvas::done_popup $win 2
        }
    }
}