Hello. I'm working on an Arduino code and accompanying Pd patch, sending values from Pd to Arduino to control the PWM value sent to certain digital pins.

As of now, the code parses incoming strings in the format int,int and ends with a carriage return. This works just fine when sending the string from the Arduino software's own serial monitor, but I cannot seem to get it work when sending messages to the [comport] object. Right now I'm just using a single banged message box (ex. [3,80]) sent to [comport], so I suspect that I need to end the message with a carriage return in some format.

How would I go about doing this? I know \ is not allowed in Pd messages. What format does the Arduino understand in this situation? Ascii?

In the code below, I suppose I could change the string terminating character to something other than a carriage return, but I would be unsure of how to execute it properly.

I'm quite new to the Arduino platform, so if anything looks and sounds completely off, please do tell me.

void setup()
{
  Serial.begin(9600);
  
}

String command;

void loop()
{
 if (Serial.available() > 0)
 {
  char c = Serial.read();
 
  if(c == '\n')
  {
    parseCommand(command);
    command = "";
  }
  else
  {
    command += c;
  }
 }
}

void parseCommand(String com)
{
  String part1;
  String part2;

  //int SPACE int
  part1 = com.substring(0, com.indexOf(","));
  part2 = com.substring(com.indexOf(",") + 1);

  int pin = part1.toInt();
  int pwmval = part2.toInt();

  analogWrite(pin, pwmval);

}

Thank you.

Hadn't seen this post, hence I'm replying so late. In Pd, the comma separates commands, so [3, 80( will send the value 30 and then the value 80 to comport, so the Arduino won't get it.
I think you're making this more complex than needed. Try this in the Arduino code:

int whichPin;
int pwmVal;
int pwmPins[2] = { 9, 10 }; // pins witn PWM capability

void setup() {
  Serial.begin(9600);
  for (int i = 0; i < 2; i++) {
    pinMode(pwmPins[i], OUTPUT);
  }
}

void loop() {
  if (Serial.available()) {
    static int tempVal;
    char inChar = Serial.read();
    if (isDigit(inChar)) {
      // assemble the value in case it's more than one digit
      tempVal = tempVal * 10 + inChar - '0';
    }
    else {
      if (inChar == 'p') {
        whichPin = tempVal;
        tempVal = 0;
      }
      else if (inChar == 'v') {
        pwmVal = tempVal;
        tempVal = 0;
        analogWrite(pwmPins[whichPin], pwmVal);
      }
    }
  }
}

Then in Pd send a message like this to [comport], "print 0p100v". This will set the value 100 to pin 9 (the first pin in the pwmPins array in the Arduino code).
There's no string assembly whatsoever in this code and it should work.

I opened up this thread on a complete whim, how lovely to see a response after so many months.
I tried out your code, alexandros - and it works just fine. I tried to add the rest of the pwm pins to the array and it worked just fine.
Can you explain why the message needs to start with "print" to work?

Also, I've found it can only take integers, so it will misread floating point numbers and read the decimal numbers as the PWM value.
Of course I can just pass whatever number box or slider through a [i] object beforehand, but just out of curiosity, how would one allow floating point numbers in that code example?

Thank you.

"print" translates all characters in a message to their ASCII bytes. So, sending "print 0p100v" to [comport], will result in 48 112 49 48 48 118 sent to the Arduino. Check ASCII table to understand this in case you don't know ASCII.
Sending floating point values to control PWM doesn't really make much sense since PWM takes bytes, so integer values from 0 to 255. I don't know if "print" will actually break a floating point value and translate the dot as well (which is ASCII 46). If you want to send floating point values to the Arduino, you should make sure the dot gets translated to ASCII (if it's not done with "print" you should probably do it with [list fromsymbol]) and then in the Arduino code look for byte 46 and do the necessary math to assemble the floating point value.